REM Demonstration of the Box2D (v2.2.1 or v2.3.1) Physics Engine
      REM by Richard Russell, http://www.rtrussell.co.uk/, 27-Jan-2013
      
      MODE 8 : OFF
      INSTALL @lib$+"box2dlib" : PROC_b2Init
      INSTALL @lib$+"box2ddbg"
      
      ON ERROR PROCcleanup : IF ERR=17 CHAIN @lib$+"../examples/tools/touchide" ELSE ERROR 0,REPORT$+" at line "+STR$ERL
      ON CLOSE PROCcleanup : QUIT
      
      gravity_x = 0.0
      gravity_y = -9.8
      scale = 20
      
      myWorld%% = FN_b2CreateWorld(gravity_x, gravity_y)
      PROC_b2DebugInit(myWorld%%, %01011, scale)
      
      ground%% = FN_b2StaticBox(myWorld%%, 16.0, 0.1, 0.0, 16.0, 0.1)
      
      n% = 20
      FOR x = 16.0 TO 28.0 STEP 12.0
        FOR i% = 0 TO n%-1
          block%% = FN_b2DynamicBody(myWorld%%, x, i%, 0, 0, 0, 0, 0, 0)
          fixture%% = FN_b2BoxFixture(block%%, 0, 0, 0, 0.5, 0.5, 0.5, 0, 0.5)
          IF x = 16.0 PROC_b2SetFilter(fixture%%, &0001, &0001, &0000)
        NEXT i%
      NEXT
      
      timeStep = 1.0/60.0
      velIterations% = 8
      posIterations% = 3
      
      bullet%% = 0
      GCOL 2
      VDU 5
      *REFRESH OFF
      REPEAT
        CLS
        
        MOUSE x%, y%, b%
        IF bullet%% = 0 IF INKEY(-99) OR b% THEN
          bullet%% = FN_b2DynamicBody(myWorld%%, 0, 10.5, 0, 200.0, 0, 0, 0, 0)
          fixture%% = FN_b2BoxFixture(bullet%%, 0, 0, 0, 0.1, 0.1, 0.1, 0, 5.0)
          PROC_b2SetFilter(fixture%%, &FFFE, &FFFF, &0000)
          PROC_b2SetBullet(bullet%%, 1)
        ENDIF
        
        PROC_b2WorldStep(myWorld%%, timeStep, velIterations%, posIterations%)
        PROC_b2DebugDraw(myWorld%%)
        MOVE 300,1000 : PRINT "Click, tap or press SPACE to fire bullet"
        *REFRESH
        WAIT 1
        IF INKEY(-1) PROC_b2DebugFlags(4, 0) ELSE PROC_b2DebugFlags(4, 4)
        
        IF bullet%% THEN
          PROC_b2GetBody(bullet%%, x, y, a)
          IF y < 1 PROC_b2DestroyBody(myWorld%%, bullet%%) : bullet%% = 0
        ENDIF
        
      UNTIL FALSE
      PROCcleanup
      END
      
      DEF PROCcleanup
      myWorld%% += 0 : IF myWorld%% PROC_b2DestroyWorld(myWorld%%) : myWorld%% = 0
      PROC_b2Exit
      ENDPROC