REM Demonstration of the Box2D (v2.2.1 or v2.3.1) Physics Engine
      REM by Richard Russell, http://www.rtrussell.co.uk/, 26-Jan-2013
      
      *TEMPO 2
      SOUND 0, 0, 0, 0
      ENVELOPE 1, 1, 0, 0, 0, 0, 0, 0, 120, -4, -4, -4, 126, 0
      MODE 8 : OFF
      INSTALL @lib$+"box2dlib" : PROC_b2Init
      INSTALL @lib$+"box2ddbg"
      
      ON ERROR PROCcleanup : IF ERR=17 CHAIN @lib$+"../examples/tools/touchide" ELSE ERROR 0,REPORT$+" at line "+STR$ERL
      ON CLOSE PROCcleanup : QUIT
      
      gravity_x = 0.0
      gravity_y = 0.0
      
      myWorld%% = FN_b2CreateWorld(gravity_x, gravity_y)
      PROC_b2DebugInit(myWorld%%, %01011, 20)
      
      ground%% = FN_b2StaticBox(myWorld%%, 16.0, -0.1, 0.0, 16.0, 0.1)
      
      DIM x(3), y(3)
      x() = 8, 8, -8, -8
      y() = 4, 20, 20, 4
      walls%% = FN_b2ChainFixture(ground%%, 4, x(), y(), 0.1, 0.0, 1.0, TRUE)
      
      FOR i% = 1 TO 3
        body%% = FN_b2DynamicBody(myWorld%%, 14.0 + i%, 12.0, 0.0, RND(50), RND(50), 0, 0, 0)
        fixture%% = FN_b2CircleFixture(body%%, 0, 0, 1.0, 0.1, 1.0, 1.0)
      NEXT i%
      
      timeStep = 1.0/60.0
      velIterations% = 8
      posIterations% = 3
      
      *REFRESH OFF
      REPEAT
        CLS
        PROC_b2WorldStep(myWorld%%, timeStep, velIterations%, posIterations%)
        PROC_b2DebugDraw(myWorld%%)
        
        contact%% = FN_b2ContactListWorld(myWorld%%)
        WHILE contact%%
          IF FN_b2IsTouching(contact%%) THEN
            SOUND 1,-15,148,1 : EXIT WHILE
          ENDIF
          contact%% = FN_b2NextContact(contact%%)
        ENDWHILE
        
        *REFRESH
        WAIT 2
        IF INKEY(-1) PROC_b2DebugFlags(4, 0) ELSE PROC_b2DebugFlags(4, 4)
      UNTIL FALSE
      PROCcleanup
      END
      
      DEF PROCcleanup
      myWorld%% += 0 : IF myWorld%% PROC_b2DestroyWorld(myWorld%%) : myWorld%% = 0
      PROC_b2Exit
      ENDPROC